Quète du minotaure [fini]

Voici le BG de la quète du Minotaure

~Quète du minotaure par Clad76~

~Inspiré de la mythologie gréco-romaine~

Le livre déclencheur de quète :

Le minotaure est issu d'une union contre-nature. Né d'une mère humaine et d'un père taureau, il porte les cicatrices de sa naissance. Iktus, pour le cacher aux yeux du monde et pour sa cruauté sans pitié, fit construire par Dédale une énorme pyramide appelé Labyrinthe, d'une telle complication que quiconque rentrait dans ce donjon se perdrait à jamais. Iktus raconta à tous que dans ce palais étaient emmenés de pauvres innocentes jeunes femmes, qui finissaient dévorés par le monstre.
On représente le Minotaure avec un corps d'homme monté d'une tête de taureau, comme pour rappeler la faute de sa mère. Cependant, à la différence des taureaux ordinaires, il se nourrit non d'herbe ou de foin, mais de chair humaine.

Ecrit par Karakath l'ancien.

Karakath l'ancien:

petite description:
auteur du livre ci-dessus, ce vieillard aime partager son savoir à la future génération de Morocc. Il se trouvera sur la place centrale de Morocc entouré d'enfants passionés par ces histoires.
Notre aventurier lui demande quelques informations sur la légende du minotaure qu'il aura lu au préalable dans le livre.
Karakath lui apprend alors que Minotaure n'était pas si méchant que sa. Bien qu'il soit d'une beauté à faire fâner une illusion flower, le Minotaure serait tombé amoureux d'une jeune femme prénommé Ariane.
"Si seulement on pouvait retrouver cette jeune femme, au moins on connaitrait la vraie histoire du minotaure ! *soupir*", dis Karakath, "La derniere fois qu'on l'a vu elle se baladait dans le desert entourant la ville..."

Cette fois-ci deux chemins s'ouvre à notre aventurier, soit aller directement dans le labyrinthe, soit d'abord se renseigner auprès de la jeune femme qu'il devra trouver parmis les 8 maps entourant Morocc. Je décrit d'abord le passage par la jeune femme.

Arianne:

Se trouve sur l'une des 8 maps entourant Morocc. Notre jeune aventurier l'ayant trouvé, il entame une discussion. Arianne lui déclare être tombé amoureux du Minotaure dans sa jeunesse, lorsque celui-ci n'était pas contraint à rester cloitré dans son labyrinthe. Ils allaient même se marier. Cependant, Iktus était jaloux du Minotaure car ils aimaient tout les deux la même femme. Iktus se vengea donc et contraint le Minotaure à se cloitrer dans un labyrinthe dont il avait ordonné la construction auprès de Dédale. Après cela, Iktus fit divulguer de fausses rumeurs sur le
Minotaure, comme quoi il ordonnait d'envoyer 14 jeunes femmes chaques années afin que celui-ci puisse se nourrir. En vérité, Minotaure restait sagement dans son labyrinthe et ne faisait rien aux gens qui y entraient à part les aider à en sortir. Puis le temps passa, Minotaure devint une légende.
Arianne supplie notre aventurier de retrouver le minotaure et de le persuader de sortir de son antre. Pour ce faire, Arianne donne son bien le plus précieux, un fil d'or qui, enchanté par une magie très puissante, permettait de trouver le chemin jusqu'à Minotaure et de lui prouver qu'Arianne est vivante et l'aime encore. Notre aventurier récupère le fil et part en direction du Labyrinthe.

Le labyrinthe:

même labyrinthe de Pyramid dungeon dont j'aurai modifié le chemin et ajouté des objets 3D pour bloquer certains passages, un vrai dédale quoi ^^". Lorsque notre jeune aventurier utilise le fil d'Arianne, celui-ci lui montre une carte avec le chemin à parcourir pour arriver jusqu'au Minotaure. Celui-ci trouvé l'aventurier aura certaines options à choisir en fonction de son comportement passé.

1) Si l'aventurier n'a pas été voir Arianne:

Soit combattre le Minotaure, soit le persuader de sortir via des arguments (en fait un questionnaire de 5 questions) La discussion sera très tendu.

2) Si l'aventurier a parlé à Arianne et qu'il a le fil d'Arianne dans son inventaire:

Soit combattre le Minotaure (stupidité), soit lui montrer le fil d'Arianne et lui dire que Arianne l'aime encore et qu'elle l'attend dehors.

Dans les deux cas l'aventurier peut engager un combat sans merci face au Minotaure:

Le combat gagné, l'aventurier récupère une récompense sur le corps du Minotaure soit des zeny, une arme de type hache (l'arme du minotaure) ainsi que de la renommé pour avoir tué le Minotaure des légendes.

Si l'aventurier arrive à le faire sortir de son labyrinthe:

Gagne des zenys (plus qu'au premier choix), de la renommé (plus qu'au premier choix), l'arme du Minotaure.


Voilà pour le Bg de la quète du Minotaure. Pour les récompenses je n'ai pas trop d'idée donc de base j'ai mis sa mais si vous

avez d'autres idées...

Voici le NPC Hakarath L'ancien qui sera le premier NPC visité par le joueur ainsi que les deux enfants qui l'entourent :

Citation :

morocc.gat,145,84,7 script Karakath L'ancien 766,{

if (#minotaure == 6) goto L_finish2;
if (#minotaure == 5) goto L_finish;
if (#minotaure == 1) goto L_arianne;
if ( countitem (12208) == 1) goto L_minotaure;

mes "[Karakath L'ancien]";
mes "...Et c'est ainsi que termine la légende du Minotaure.";
next;
mes "[Joshy]";
mes "Ouaaaaah, encore, encore une histoire!";
next;
mes "[Pierre]";
mes"Owiii, encore une histoire s'il vous plait papy!";
close;

L_minotaure:
mes "[Karakath L'ancien]";
mes "Hum? êtes-vous interessé par les légendes?";
menu "En apprendre plus sur le Minotaure",L_minos,"Les légendes, non merci",L_partir;

L_minos:
mes "^FF00FF*Il porte son regarde sur un livre qui dépasse de votre sac*^000000";
next;
mes "[Karakath L'ancien]";
mes "Mais c'est mon livre que tu portes? c'est d'accord je veut bien t'en dire plus sur ^00FFFFle Minotaure^000000.";
next;
mes "[Karakath L'ancien]";
mes "^00FFFFMinotaure^000000 est souvent comparé à une créature sanguinaire et débordant de violence et de cruauté. Cependant, les faibles esprits n'ont jamais entendu parler de la véritable histoire du ^00FFFFMinotaure^000000.";
next;
mes "[Karakath L'ancien]";
mes "Bien qu'il soit laid à en faire fâner une Illusion flower, ^00FFFFle Minotaure^000000 serait tombé amoureux d'une jeune femme prénommé ^00FFFFArianne^000000.";
next;
mes "[Karakath L'ancien]";
mes "Si seulement on pouvait retrouver cette jeune femme, au moins on connaitrait la vraie histoire du ^00FFFFMinotaure^000000 !";
next;
mes "^FF00FF*Il pousse un soupir bruyant*^000000";
next;
goto L_arianne;
close;

L_arianne:
set #minotaure,1;
mes "[Karakath L'ancien]";
mes "La derniere fois qu'elle a été aperçu elle errait dans ^00FF00le désert entourant la ville^000000";
close;

L_finish:
mes "[Karakath L'ancien]";
mes "Eh bien, il semble que Minotaure n'était pas une légende et que celui-ci est mort...";
next;
mes "^FF00FF*Il pousse un long soupir*^000000";
close;

L_finish2:
mes "[Karakath L'ancien]";
mes "...Et c'est ainsi que se finit la merveilleuse histoire de la belle Arianne et de son amant, ^00FFFFle Minotaure^000000...";
close;

L_partir:
mes "[Karakath L'ancien]";
mes "Les légendes ne sont pas forcément inventées, certaines sont véridiques et peuvent apporter fortune à ceux qui s'y intéressent.";
close;
}

///////// Joshy //////////
morocc.gat,148,85,4 script Josh 62,{

if (#minotaure == 6) goto L_finish;

mes "[Joshy]";
mes "Les histoires de Karakath sont passionantes.";
close;

L_finish:
mes "[Joshy]";
mes "Quand je serait grande, moi aussi j'aurait un mari aussi fort que ^00FFFFle Minotaure^000000 !";
close;

}

//////// Pierre ////////
morocc.gat,146,88,4 script Josh 82,{

if (#minotaure == 6) goto L_finish;

mes "[Pierre]";
mes "Un jour je tuerait ^00FFFFle Minotaure^000000 de mes propres mains !! ";
close;

L_finish:
mes "[Pierre]";
mes "Tout bien réfléchit, je vais m'entrainer dur afin de devenir aussi fort et brave que ^00FFFFle Minotaure^000000 !";
close;
}

Voici le second NPC qui n'est pas obligatoire dans la quète, Arianne:

Citation :

moc_ruins.gat,109,62,4 script Arianne 760,{

if (#minotaure == 6) goto L_finish3;
if (#minotaure == 5) goto L_finish;
if (#minotaure == 4) goto L_finish2;
if (#minotaure > 1) goto L_help2;
if (#minotaure == 1) goto L_minos;

mes "[Arianne]";
mes "........";
next;
mes "^FF00FF*Une larme coule de sa joue et tombe sur le sable*^000000";
close;

L_minos:

mes "[Arianne]";
mes "... Ainsi tu t'intéresses à notre histoire? ^00FFFFMinotaure^000000 et moi?";
next;
mes "[Arianne]";
mes "L'histoire tel qu'elle était la voici...";
next;
mes "[Arianne]";
mes "^00FFFFMinotaure^000000 et moi-même sommes tombés amoureux l'un l'autre. La beauté ne comptait pas dans notre relation...";
next;
mes "[Arianne]";
mes "Nous enviseagions même de nous marier lorsque ^00FFFFIktus^000000 se montra d'un tempérament violent.";
next;
mes "[Arianne]";
mes "^00FFFFIktus^000000 était à l'époque le dirigeant de la ville de Morocc. Il était secrètement amoureux de moi et n'a pas supporté le choc de voir ^00FFFFMinotaure^000000 et moi ensemble.";
next;
mes "[Arianne]";
mes "Il a ordonné à ^00FFFFDédale^000000, le meilleure architecte de tout les temps, de construire une pyramide abritant un ^00FF00Labyrinthe^000000 afin d'y enfermer ^00FFFFle Minotaure^000000...";
next;
mes "[Arianne]";
mes "C'est ainsi que nous fûmes séparés l'un de l'autre. De plus, ^00FFFFIktus^000000 fît circuler de fausses rumeurs comme quoi ^00FFFFMinotaure^000000 avait ordonné de lui attribuer 14 jeunes femmes chaques années afin qu'il puisse manger à sa faim.";
next;
mes "[Arianne]";
mes "En vérité, ^00FFFFMinotaure^000000 restait bien sagement dans ^00FF00le Labyrinthe^000000, se nourrissant des monstres qui y vivaient et aidant les pauvres personnes qui s'y étaient aventurés par mégarde.";
next;
mes "[Arianne]";
mes "Avec le temps, ^00FFFFMinotaure^000000 devînt une légende... Alors qu'il est toujours enfermé dans son labyrinthe...";
next;
menu "Je souhaite vous aider",L_help,"Cette histoire ne me plait pas",L_partir;

L_help:
mes "[Arianne]";
mes "Vraiment? comme c'est gentil à vous ! ";
next;
mes "[Arianne]";
mes "A vrai dire, j'aimerait que vous m'aidiez à sortir ^00FFFFMinotaure^000000 de ^00FF00son Labyrinthe^000000.";
next;
mes "[Arianne]";
mes "Pour ce faire, aidez-vous de ce fil, il vous indiquera le chemin à prendre pour vous liberer de ^00FF00ce Labyrinthe^000000.";
getitem 12209,1;
goto L_help2;
close;

L_help2:
set #minotaure,2;
mes "[Arianne]";
mes "Ce fil vous permettra non seulement de vous guider dans ^00FF00le Labyrinthe^000000 mais permettra aussi de convaincre ^00FFFFMinotaure^000000 d'y sortir.";
next;
mes "[Arianne]";
mes "L'entrée du ^00FF00Labyrinthe^000000 se trouve ici!";
viewpoint 1,147,167,2,0x0000FF;
close;

L_finish:
mes "[Arianne]";
mes "Ooooooh, pardonne-moi ^00FFFFMinotaure^000000, j'aurait dû venir te voir... Mais j'avais si peur !";
next;
mes "^FF00FF*Elle fond en larme, sa tête entre ses mains*^000000";
close;

L_finish2:
mes "[Arianne]";
mes "Alors comme sa tu as réussis à persuader ^00FFFFMinotaure^000000 de venir me rendre visite de temps en temps?";
next;
mes "^FF00FF*Elle devient rayonnante de joie*^000000";
next;
mes "[Arianne]";
mes "Oh, Par la gloire du Soleil, grand joie s'en face !!";
next;
mes "[Arianne]";
mes "Je te remercie de tout coeur pour ta vaillance et ta gentillesse!";
next;
delitem 12209,1;
mes "[Arianne]";
mes "Accepte-donc ces récompenses, tu les mérites bien !";

//Les récompenses seront ici
//Mais que mettre? ^^"

set #minotaure,6;
goto L_finish3;

L_finish3:
mes "[Arianne]";
mes "J'attendrait donc patiemment la venu de ^00FFFFMinotaure^000000 !!!";
close;


L_partir:
mes "[Arianne]";
mes "au revoir ....";
next;
mes "^FF00FF*Une larme coule lentement de son oeil gauche*^000000";
close;
}

Voici le script du NPC qui vous fera entrer dans le Labyrinthe:

Citation :

moc_ruins.gat,147,164,4 script Guide 100,{

if (#minotaure == 6) goto L_noentrance2;
if (#minotaure == 4) goto L_noentrance2;
if (#minotaure == 5) goto L_noentrance;

mes "[Guide]";
mes "Ici se trouve le chef-d'oeuvre de ^00FFFFDédale^000000, la pyramide abritant ^00FF00le Labyrinthe^000000";
next;
menu "Demander à entrer dans le Labyrinthe",L_warp,"Partir",L_partir;

L_warp:
warp "pyramide.gat",93,95;
close;

L_noentrance:
mes "[Guide]";
mes "Je suis désolé mais vous ne pouvez plus accéder au ^00FF00Labyrinthe^000000, une bête féroce y aurait été tué et les guardes de Morocc ont fermés l'accès.";
close;

L_noentrance2:
mes "[Guide]";
mes "Je suis désolé mais l'accès au ^00FF00Labyrinthe^000000 de ^00FFFFDédale^000000 est interdit maintenant...";
close;

L_partir:
close;
}

Voici le script du fameux Minotaure , le plus long:

Citation :

pyramide.gat,215,10,4 script Minotaure 1149,{

if (#minotaure == 4) goto L_finish2;
if ( countitem (12209) == 1) goto L_filant;

mes "[Minotaure]";
mes "Grumble, encore un qui c'est perdu !";
next;
mes "^FF00FF*Il commence à taper du pied*^000000";
next;
mes "[Minotaure]";
mes "Oh...Arianne, elle doit sûrement être en vie...";
menu "Combattre Minotaure",L_combat,"Le persuader de sortir d'ici",L_sortir;

L_filant:
mes "[Minotaure]";
mes "Grumble, encore un qui c'est perdu !";
next;
mes "^FF00FF*Remarque le fil d'Arianne qui dépasse de votre sac*^000000";
next;
mes "[Minotaure]";
mes "Oh...ce fil, ne serait-ce pas celui d'Arianne?";
menu "Oui, elle souhaite te voir",L_filant2,"Horrible monstre, tu vas mourir!",L_combat;

L_filant2:
next;
mes "[Minotaure]";
mes "Qu...que...comment sa? me voir? moi?";
next;
mes "^FF00FF*Vous lui racontez toute l'histoire*^000000";
next;
mes "[Minotaure]";
mes "Ainsi je comprend mieux... Je n'aurait jamais dû errer dans ce Labyrinthe tout ce temps alors qu'elle m'attendait dehors...";
next;
mes "[Minotaure]";
mes "Merci à toi de m'avoir apporté de ces nouvelles. Maintenant retourne la voir et dis lui que je passerait de temps à autre lui rendre visite.";
set #minotaure,4;
goto L_finish2;
close;

L_finish2:
mes "[Minotaure]";
mes "Mon devoir est aussi d'aider les gens qui se perdent dans ce labyrinthe sans fin, encore merci à toi !";
close;

// S'il engage le combat !

L_combat:
mes "[Minotaure]";
mes "Et tu crois peut-être pouvoir me battre, MOUAHAHAHAHAH!";
next;
mes "[Minotaure]";
mes "Par la force de ma hache, je vais te découper en rondelle pour cet affront déplacé !";
next;
hideonnpc "Minotaure";
set $killminos,0;
monster "pyramide.gat",214,10,"Minotaure",1310,1,"Minos::OnMinosMobDead";
close;


// S'il décide de le faire sortir sans le fil d'Arianne !

L_sortir:
mes "[Minotaure]";
mes "Hummm? et pourquoi devrais-je sortir d'ici?";
menu "J'ai entendu parler d'une Arianne",L_arianne,"Il y a pleins de choses interessantes",L_wrong;

L_arianne:
next;
mes "[Minotaure]";
mes "A...Arianne? elle est encore vivante?";
menu "Pourquoi pas?",L_wrong2,"Pour le savoir il faudrait sortir",L_arianne1;

L_arianne1:
next;
mes "[Minotaure]";
mes "Oh, Arianne, elle me manque tellement...";
menu "Pourquoi ne pas aller la voir?",L_arianne2,"Bon moi je vais y aller!",L_wrong3;

L_arianne2:
next;
mes "[Minotaure]";
mes "N...Non, je n'oserait jamais...";
menu "Eh bien reste ici !",L_wrong4,"Il le faut !",L_arianne3;

L_arianne3:
next;
mes "[Minotaure]";
mes "Et pourquoi donc?";
menu "A toi de me le dire...",L_arianne4,"Pour aller la voir",L_wrong5;

L_arianne4:
mes "[Minotaure]";
mes "N...non il ne faut pas... Mais je l'aime tellement !";
next;
mes "[Minotaure]";
mes "M...mais... Mais oui tout devient clair... J'en ai plus qu'assez de rester enterré dans mon trou à Verit !";
next;
mes "[Minotaure]";
mes "Maintenant je prendrait mon courage à deux mains et j'irait la voir, merci jeune aventurier de m'avoir ouvert les yeux !";
next;
mes "[Minotaure]";
mes "Pour ta gentillesse et ta bravoure je te donnes mes biens, tu en tireras beaucoup de gloire.";

//Je penserait à mettre la recompense ici
//Mais comme j'ai aucune idée de quoi...

set #minotaure,4;
goto L_theend;

L_theend:
mes "[Minotaure]";
mes "Encore merci, maintenant je vais t'indiquer la sortie... Bonne chance à toi par la suite !";
warp "moc_ruins.gat",147,162;
close;

L_wrong5:
next;
mes "[Minotaure]";
mes "Je ne pense pas que se soit une bonne idée...Maintenant laisse-moi tranquille !";
close;

L_wrong4:
next;
mes "[Minotaure]";
mes "Grumble, eh toi tu n'as qu'a partir de mon antre, dehors !";
close;

L_wrong3:
next;
mes "[Minotaure]";
mes "Grumble, eh bien part, et ne remet plus les pieds ici !";
close;

L_wrong2:
next;
mes "[Minotaure]";
mes "Grumble, cette réponse ne me plait guère...";
close;

L_wrong:
next;
mes "[Minotaure]";
mes "Grumble, je préfère rester ici à me lamenter sur mon sort...";
close;
}

- script Minos -1,{
OnMinosMobDead:
set $killminos,$killminos+1;
if $killminos == 1 callfunc "minos";
end;
}

function script minos {

hideoffnpc "Minotaure";
set #minotaure,5;
set $killminos,0;
mapannounce "pyramide.gat","[Minotaure]: Je me vengerait " + strcharinfo(0) + ", Arianne je rejoint les cieux, ne m'en veut pas...",8;

//Pour ma part je pense rajouter la récompense ici mais je sais
//pas quoi donner alors je vous laisse faire ^^"

warp "moc_ruins.gat",147,162;
end;

}

Voici les deux différents chemins.


L'ancien chemin, soit le second étage de pyramid dungeon, l'originale:



Et voici celui du Labyrinthe du Minotaure que j'ai modifié:




Et pour la route un screen de cette map que j'ai modifié (ajout d'eau, changement d'éclairage, ajout de piliers cassés pour bloquer certains passages)